;Program: MER_AKO1 Měření kmitočtu do 255 Hz
;****************************************************************************
	LIST P = 16F84,	R = DEC
	#INCLUDE <P16F84.INC>
;----------------------------------------------------------------------------
 __CONFIG   _CP_OFF & _WDT_OFF & _PWRTE_ON & _XT_OSC
;****************************************************************************

RAM	EQU	H'0C'
RBF	EQU	RAM
RBF1	EQU	RAM+1
NUM	EQU	RAM+2
TMP	EQU	RAM+3
TM1	EQU	RAM+4
TM2	EQU	RAM+5
TM3	EQU	RAM+6
JEDN	EQU	RAM+7
DES	EQU	RAM+8
STA	EQU	RAM+9

#define	Q	PORTB,0
#define	RS	PORTB,1	
#define	RW	PORTB,2
#define	E	PORTB,3
#define	BF	RBF,3
;****************************************************************************
	ORG	0
	GOTO	START

;----------------------------------------------------------------------------
;podprogramy
;----------------------------------------------------------------------------
INILCD	CALL	t15mS		;doba 15 milisekund
	BCF	RS
	BCF	RW
	CALL	A_OUT		;port A výstup
	BSF	E
	MOVLW	B'00000011'
	MOVWF	PORTA
	BCF	E
	CALL	t4mS		;doba 4 milisekund
	BSF	E
	MOVLW	B'00000011'
	MOVWF	PORTA
	BCF	E
	CALL	t100uS		;doba 100 mikrosekund
	BSF	E
	MOVLW	B'00000011'
	MOVWF	PORTA
	BCF	E
	CALL	t100uS		;doba 100 mikrosekund
	MOVLW	B'00101000'
	CALL	WRPRI		;4.bitová komunikace a dva řádky
	MOVLW	B'00001000'
	CALL	WRPRI		;displej OFF
	MOVLW	B'00001100'
	CALL	WRPRI		;displej ON, kurzor OFF, blikání OFF
	MOVLW	B'00000110'
	CALL	WRPRI		;inkrementace, normální operace
	RETURN
;----------------------------------------------------------------------------
WRDATA	BSF	RS		;nastavení bitu RS pro zápis dat
	GOTO	$+2
WRPRI	BCF	RS		;nastavení bitů RS a RW pro zápis příkazu
	BCF	RW
	MOVWF	TMP		;číslo příkazu nebo data do registru TMP
	CALL	A_OUT		;portA jako výstup
	SWAPF	TMP,W		;horní 4 bity do registru W
	BSF	E
	MOVWF	PORTA		;zápis 4 horních bitů do displeje
	BCF	E
	MOVFW	TMP		;obsah registru TMP do registru W
	BSF	E
	MOVWF	PORTA		;zápis dolních 4 bitů do displeje
	BCF	E
	CALL	T_BF		;testování bitu BF
	RETURN
;----------------------------------------------------------------------------
T_BF	BCF	RS		;podprogram testuje konec operace (bit BF)
	BSF	RW
	CALL	A_IN		;portA vstup (po ukončení zase výstup)
	BSF	E
	MOVFW	PORTA
	MOVWF	RBF
	BCF	E
	NOP
	BSF	E
	MOVFW	PORTA
	MOVWF	RBF1
	BCF	E
	BTFSC	BF		;je bit BF=0 ? (0 = konec operace)
	GOTO	$-10		;ne - testuj znova
;----------------------------------------------------------------------------
A_OUT	MOVLW	B'11110000'	;pin A0/A3 výstup, pin A4 vstup
	GOTO	$+2
A_IN	MOVLW	B'11111111'	;pin A0/A7 vstup
	BSF	STATUS,RP0	;banka 1
	MOVWF	TRISA		;nastavení portu A
	BCF	STATUS,RP0	;banka 0
	RETURN
;****************************************************************************
t15mS	MOVLW	49		;doba 15 milisekund
	GOTO	$+2
t4mS	MOVLW	14		;doba 4 milisekund
	MOVWF	TM1
	MOVLW	255
	MOVWF	TM2
	DECFSZ	TM2,F
	GOTO	$-1
	DECFSZ	TM1,F
	GOTO	$-5
	RETURN
;----------------------------------------------------------------------------
t100uS	MOVLW	83		;doba 100 mikrosekund
	MOVWF	TM1
	DECFSZ	TM1,F
	GOTO	$-1
	RETURN
;----------------------------------------------------------------------------
t1S	MOVLW	100		;doba 1 sekundy
	MOVWF	TM3
	NOP
	MOVLW	19
	MOVWF	TM1
	MOVLW	174
	MOVWF	TM2
	DECFSZ	TM2,F
	GOTO	$-1
	DECFSZ	TM1,F
	GOTO	$-5
	DECFSZ	TM3,F
	GOTO	$-10
	RETURN
;****************************************************************************

PREVOD	CLRF	DES		;vynulování desítek
	CLRF	STA		;vynulování stovek
	MOVLW	100
	SUBWF	NUM,W		;registr NUM=NUM-100
	BTFSS	STATUS,C	;došlo k podtečení?
	GOTO	$+4		;ano,proveď skok
	MOVWF	NUM		;ne
	INCF	STA,F		;registr STA=STA+1
	GOTO	$-6		;a znova dokola
	MOVLW	10
	SUBWF	NUM,W		;registr NUM=NUM-10
	BTFSS	STATUS,C	;došlo k podtečení?
	GOTO	$+4		;ano,proveď skok
	MOVWF	NUM		;ne
	INCF	DES,F		;registr DES=DES+1
	GOTO	$-6		;a znova dokola
	MOVLW	48
	ADDWF	STA,F		;registr STA+48
	ADDWF	DES,F		;registr STA+48
	ADDWF	NUM,W		;zbytek do registru W
	MOVWF	JEDN		;registr JEDN=W+48
	RETURN
;****************************************************************************

;program
;----------------------------------------------------------------------------
START	BSF	STATUS,RP0	;banka 1
	MOVLW	B'11110001'	
	MOVWF	TRISB		;nastavení portu B
	MOVLW	B'11101000'
	MOVWF	OPTION_REG	;nastavení OPTION_REG
	BCF	STATUS,RP0	;banka 0

	CALL	INILCD		;inicializace displeje
	MOVLW	1
	CALL	WRPRI		;reset displeje

	MOVLW	42
	CALL	WRDATA		;tisk "*"

	CLRF	PORTA		;nula na port A
	BTFSS	Q		;je stisknuto tlačítko ENTER
	GOTO	$-1		;ne,tak čekej

	CLRF	TMR0		;vynulování registru TMR0

	CALL	t1S		;doba 1 sekundy

	MOVFW	TMR0
	MOVWF	NUM		;obsah TMR0 do NUM
	CALL	PREVOD		;proveď převod

	MOVFW	STA
	CALL	WRDATA		;tisk stovek
	MOVFW	DES
	CALL	WRDATA		;tisk desítek
	MOVFW	JEDN
	CALL	WRDATA		;tisk jednotek
	MOVLW	32
	CALL	WRDATA		;tisk mezery
	MOVLW	72
	CALL	WRDATA		;tisk "H"
	MOVLW	122
	CALL	WRDATA		;tisk "z"

	GOTO	$-0		;věčná smyčka
	END
